# NOTICE:
#
# Application name defined in TARGET has a corresponding QML filename.
# If name defined in TARGET is changed, the following needs to be done
# to match new name:
#   - corresponding QML filename must be changed
#   - desktop icon filename must be changed
#   - desktop filename must be changed
#   - icon definition filename in desktop file must be changed
#   - translation filenames have to be changed

LISP_FILES = make.lisp \
    lisp/system-index.txt \
    lisp/local-projects/app/app.lisp \
    lisp/local-projects/app/app.asd

lisp.output = libapp.a
lisp.commands = eql5 -platform minimal $$PWD/make.lisp
lisp.input = LISP_FILES
lisp.CONFIG = combine target_predeps

QMAKE_EXTRA_COMPILERS += lisp

# The name of your application
TARGET = eql5-sfos

CONFIG += sailfishapp
LIBS += -L. -lapp -lecl -leql5
QT   += widgets qml multimedia network quick sql

norepl|standalone:lisp.commands = eql5 -platform minimal $$PWD/make.lisp norepl

standalone {
    CONFIG += link_prl
    LIBS   -= -lecl -leql5
    LIBS   += -l:libecl.a -l:libeclatomic.a -l:libeclgc.a -l:libeclgmp.a -l:libeclffi.a -l:libeql5.a
}

SOURCES += src/eql5-sfos.cc

DISTFILES += qml/eql5-sfos.qml \
    qml/cover/CoverPage.qml \
    qml/pages/FirstPage.qml \
    qml/pages/SecondPage.qml \
    rpm/eql5-sfos.changes.in \
    rpm/eql5-sfos.changes.run.in \
    rpm/eql5-sfos.spec \
    rpm/eql5-sfos.yaml \
#    translations/*.ts \
    eql5-sfos.desktop

SAILFISHAPP_ICONS = 86x86 108x108 128x128 172x172

# to disable building translations every time, comment out the
# following CONFIG line
# CONFIG += sailfishapp_i18n

# German translation is enabled as an example. If you aren't
# planning to localize your app, remember to comment out the
# following TRANSLATIONS line. And also do not forget to
# modify the localized app name in the the .desktop file.
# TRANSLATIONS += translations/eql5-sfos-de.ts